配置kubeconfig凭证#

kubeconfig凭证用于为集群执行kubectl命令提供凭证，添加方式

1. 点击凭证->创建
2. 类型选择kubeconfig，内容会自动填充，不用修改
3. 名称输入：kubeconfig
4. 点击确定

配置镜像仓库凭证#

添加镜像仓库凭证，为登录镜像仓库平台提供用户名和密码

1. 点击凭证->创建 2.类型选择用户名和密码， 3.名称输入：harbor
2. 输入镜像仓库的用户名和密码
3. 点击确定

Jenkinsfile文件#

执行jenkins流水线的声明文件，在构建镜像使用到了Dockefile文件

pipeline {
  agent {
    kubernetes {
      // 继承KubeSphere自带的nodejs容器
      inheritFrom 'nodejs base'
      containerTemplate {
        // 容器名称，提供给下面的stage使用
        name 'nodejs'
        // 使用国内可以访问的镜像指定nodejs版本
        image 'docker.1ms.run/node:18-alpine'
      }
    }
  }

  // 环境变量
  environment {
    // 镜像仓库域名，不可删除
    REGISTRY = 'harbor.nick-h.cn'
    // 镜像仓库名称，不可删除
    DOCKERHUB_NAMESPACE = 'qq742037091'
    // 镜像应用名称，不可删除
    APP_NAME = 'demo'
    // 使用环境变量组装镜像名称，BUILD_NUMBER为流水线编号
    DOCKER_IMAGE = "${REGISTRY}/${DOCKERHUB_NAMESPACE}/${APP_NAME}:snapshot-${BUILD_NUMBER}"
    // 项目名称
    DEPLOYMENT_NAMESPACE = 'demo-project'
    // 工作负载名称
    DEPLOYMENT_NAME = 'demo-service-v1'
    // 容器名称
    CONTAINER_NAME = 'demo-container'
  }

  stages {
    // 拉取代码
    stage('Clone repository') {
      steps {
          checkout(scm)
      }
    }

    // 安装依赖
    stage('Run npm install') {
      steps {
        // 使用agent中定义的的nodejs容器
        container('nodejs') {
          // 使用国内npm源，加速安装
          sh 'npm config set registry https://registry.npmmirror.com'
          sh 'npm install'
        }

      }
    }

    // 生产构建文件
    stage('Run npm build') {
      steps {
        // 使用agent中定义的的nodejs容器
        container('nodejs') {
          sh 'npm run build'
        }
      }
    }

    // 构建镜像并推送到镜像参考
    stage('Run docker build') {
      agent none
      steps {
        // 使用kubesphere自带的base镜像，可以执行docker命令
        container('base') {
          sh 'docker build -f /deploy/Dockerfile -t $DOCKER_IMAGE .'
          // 使用私有的镜像仓库凭证，名称：harbor
          withCredentials([usernamePassword(credentialsId: 'harbor', passwordVariable: 'DOCKER_PASSWORD', usernameVariable: 'DOCKER_USERNAME')]) {
            // 登录镜像仓库
            sh 'echo "$DOCKER_PASSWORD"|docker login $REGISTRY -u "$DOCKER_USERNAME" --password-stdin'
            // 推送镜像
            sh 'docker push $DOCKER_IMAGE'
          }
        }
      }
    }

    // 部署到Kubernetes
    stage('Deploy to Kubernetes') {
        steps {
            script {
                // 使用配置好的Kubernetes凭证，名称：kubeconfig
                withCredentials([kubeconfigFile(credentialsId: 'kubeconfig', variable: 'KUBECONFIG')]) {
                  // 使用kubesphere自带的base镜像，可以执行kubectl命令
                  container('base') {
                    // 使用kubectl命令，更新工作负载镜像名称，注意这里每次构建的镜像名称都不一样
                    sh """
                      kubectl set image deployment/${DEPLOYMENT_NAME} ${CONTAINER_NAME}=${DOCKER_IMAGE} -n ${DEPLOYMENT_NAMESPACE}
                    """
                    // 获取部署结果
                    sh """
                      kubectl rollout status deployment/${DEPLOYMENT_NAME} -n ${DEPLOYMENT_NAMESPACE}
                    """
                  }
                }
            }
        }
    }
  }
}

Dockefile文件#

构建镜像的配置文件，使用到nignx配置文件

# 拉取国内的nginx镜像
FROM docker.1ms.run/nginx:alpine-perl
# 暴露80端口
EXPOSE 80
# 复制构建文件到nginx http根目录
COPY ./dist /usr/share/nginx/html
# 删除默认nginx配置
RUN rm /etc/nginx/conf.d/default.conf
# 复制自定义nginx配置
COPY ./deploy/nginx.conf /etc/nginx/conf.d/